ShowUsYour<Blog>

Option Strict On


Imports System
Imports System.ComponentModel
Imports System.Configuration
Imports System.Data
Imports System.Drawing
Imports System.Web.UI
Imports System.Web.UI.WebControls



'*********************************************************************
'
' KPIs Class
'
' WebControl that displays a listing of KPIs for a given Category/Month. 
'
'*********************************************************************

< _
 Description("WebControl that displays a listing of KPIs for a given Category/Month."), _
 DefaultProperty("DataSource"), _
 Designer(GetType(KPIsDesigner)), _
 ToolboxData("<{0}:KPIs runat=server></{0}:KPIs>") _
> _
Public Class KPIs
    Inherits Web.UI.WebControls.Table
    Implements INamingContainer

    Private mstrCategoryName As String = String.Empty
    Private mstrNavigateUrl As String = String.Empty
    Private mstrBaseImagePath As String = String.Empty
    Private mdtmSelectedMonth As DateTime = DateTime.MinValue
    Private mDatasource As DataTable

    '*********************************************************************
    '
    ' BaseImagePath Property
    '
    ' The directory to look in to find the images.
    '
    '*********************************************************************
    < _
        Browsable(True), _
        Description("The directory to look in to find the images."), _
        Category("Data") _
    > _
    Public Property BaseImagePath() As String
        Get
            Return Me.mstrBaseImagePath
        End Get
        Set(ByVal Value As String)
            Me.mstrBaseImagePath = Value
        End Set
    End Property


    '*********************************************************************
    '
    ' CategoryName Property
    '
    ' The CategoryName to filterBy.
    '
    '*********************************************************************
    < _
        Browsable(True), _
        Description("The name of the current category being displayed."), _
        Category("Data") _
    > _
    Public Property CategoryName() As String
        Get
            Return Me.mstrCategoryName
        End Get
        Set(ByVal Value As String)
            Me.mstrCategoryName = Value
        End Set
    End Property


    < _
        Browsable(True), _
        Description("The foreground color for alternating items in the table."), _
        Category("Appearance") _
    > _
    Public Property AlternatingForeColor() As Color
        Get
            If ViewState("AlternatingForeColor") Is Nothing Then
                Return Me.ForeColor
            Else
                Return CType(ViewState("AlternatingForeColor"), Color)
            End If
        End Get
        Set(ByVal Value As Color)
            ViewState("AlternatingForeColor") = Value
        End Set
    End Property


    < _
        Browsable(True), _
        Description("The background color for alternating items in the table."), _
        Category("Appearance") _
    > _
    Public Property AlternatingBackColor() As Color
        Get
            If ViewState("AlternatingBackColor") Is Nothing Then
                Return Me.ForeColor
            Else
                Return CType(ViewState("AlternatingBackColor"), Color)
            End If
        End Get
        Set(ByVal Value As Color)
            ViewState("AlternatingBackColor") = Value
        End Set
    End Property


    < _
        Browsable(True), _
        Description("The DataTable to use as a datasource."), _
        Category("Data") _
    > _
    Public Property DataSource() As DataTable
        Get
            Return Me.mDatasource
        End Get
        Set(ByVal Value As DataTable)
            Me.mDatasource = Value
        End Set
    End Property




    '*********************************************************************
    '
    ' NavigateUrl Property
    '
    ' The Url to navigate to to display the details for a given KPI
    '
    '*********************************************************************
    < _
        Browsable(True), _
        Description("The Url to navigate to to display the details for a given KPI.  Uses a {0} placeholder to insert the Id of the KPI."), _
        Category("Data") _
    > _
    Public Property NavigateUrl() As String
        Get
            Return Me.mstrNavigateUrl
        End Get
        Set(ByVal Value As String)
            Me.mstrNavigateUrl = Value
        End Set
    End Property


    '*********************************************************************
    '
    ' Controls Property
    '
    ' Make sure that when you access a child control, the
    ' CreateChildControls method has been called.
    '
    '*********************************************************************
    Public Overrides ReadOnly Property Controls() As ControlCollection
        Get
            EnsureChildControls()
            Return MyBase.Controls
        End Get
    End Property


    '*********************************************************************
    '
    ' SelectedMonth Property
    '
    ' The SelectedMonth to filterBy.
    '
    '*********************************************************************
    < _
        Browsable(True), _
        Description("The resultset is filtered by the Month of the DateTime that is passed in."), _
        Category("Data") _
    > _
    Public Property SelectedMonth() As DateTime
        Get
            Return Me.mdtmSelectedMonth
        End Get
        Set(ByVal Value As DateTime)
            Me.mdtmSelectedMonth = Value
        End Set
    End Property



    Protected Overrides Sub CreateChildControls()
        Controls.Clear()

        If mDatasource Is Nothing Then
            mDatasource = GetData()
        End If

        If Not mDatasource Is Nothing Then
            Me.Rows.Add(BuildHeaderRow())

            For Each row As DataRow In mDatasource.Rows
                Dim KPIId As Integer = Convert.ToInt32(row.Item("kpiId"))
                Dim KPIDescription As String = row.Item("kpiDescription").ToString

                Dim mtdRaw As Double = Convert.ToDouble(row.Item("mtdRawValue"))
                Dim ytdRaw As Double = Convert.ToDouble(row.Item("ytdRawValue"))
                Dim mtdDisplay As Integer = Convert.ToInt32(row.Item("mtdDisplayFlag"))
                Dim ytdDisplay As Integer = Convert.ToInt32(row.Item("ytdDisplayFlag"))

                Dim alternating As Boolean = (Me.Rows.Count Mod 2 = 0)
                Me.Rows.Add(BuildRow(KPIId, KPIDescription, mtdRaw, ytdRaw, mtdDisplay, ytdDisplay, alternating))
            Next
        End If
    End Sub


    '*********************************************************************
    '
    ' Render Method
    '
    '*********************************************************************
    Protected Overrides Sub Render(ByVal tw As HtmlTextWriter)
        MyBase.Render(tw)
    End Sub ' Render


    Private Function BuildRow(ByVal kpiId As Integer, ByVal kpiDescription As String, ByVal mtdRaw As Double, _
            ByVal ytdRaw As Double, ByVal mtdDisplay As Integer, ByVal ytdDisplay As Integer, ByVal isAlternatingItem As Boolean) As TableRow
        Dim cell As TableCell
        Dim row As New TableRow

        If isAlternatingItem Then
            row.ForeColor = Me.AlternatingForeColor
            row.BackColor = Me.AlternatingBackColor
        End If

        Dim link As New HyperLink
        link.Text = kpiDescription
        If Not Me.mstrNavigateUrl Is String.Empty Then
            link.NavigateUrl = String.Format(Me.NavigateUrl, kpiId)
        End If

        cell = New TableCell
        cell.Controls.Add(link)
        row.Cells.Add(cell)


        cell = New TableCell
        cell.Controls.Add(GetImage(mtdDisplay, mtdRaw, "MTD"))
        row.Cells.Add(cell)


        cell = New TableCell
        cell.Controls.Add(GetImage(ytdDisplay, ytdRaw, "YTD"))
        row.Cells.Add(cell)

        Return row
    End Function


    Private Function BuildHeaderRow() As TableRow
        Dim cell As TableCell
        Dim row As New TableRow

        cell = New TableHeaderCell
        cell.Text = "&nbsp;"
        row.Cells.Add(cell)

        cell = New TableHeaderCell
        cell.Text = "MTD"
        row.Cells.Add(cell)

        cell = New TableHeaderCell
        cell.Text = "YTD"
        row.Cells.Add(cell)

        Return row
    End Function


    Private Function GetData() As DataTable
        Return Nothing
    End Function


    '*********************************************************************
    '
    ' GetImage Method
    '
    ' Returns the appropriate image for a particular rating.
    '
    '*********************************************************************
    Friend Function GetImage(ByVal ratingNumber As Integer, ByVal rawVal As Double, ByVal desc As String) As Web.UI.WebControls.Image
        Dim img As New Web.UI.WebControls.Image

        If Me.mstrBaseImagePath <> String.Empty Then
            If ratingNumber = 1 Then
                img.ImageUrl = Page.ResolveUrl(String.Format("{0}/Green.gif", Me.mstrBaseImagePath))
            ElseIf ratingNumber = 2 Then
                img.ImageUrl = Page.ResolveUrl(String.Format("{0}/Yellow.gif", Me.mstrBaseImagePath))
            ElseIf ratingNumber = 3 Then
                img.ImageUrl = Page.ResolveUrl(String.Format("{0}/Red.gif", Me.mstrBaseImagePath))
            Else
                img.ImageUrl = Page.ResolveUrl(String.Format("{0}/Spacer.gif", Me.mstrBaseImagePath))
            End If
        End If

        img.AlternateText = String.Format("{1} : {0}", rawVal, desc)
        Return img
    End Function 'GetImage 


End Class